Progression Command用 MultiListenコマンド

2010年11月12日

Progression Command の Listenコマンドを用いると、イベント待ちがコマンドリストのなかでおこなえるんけれども、
複数のイベント待ちを行いたいときどうしたらいいかわからなかったので
MultiListenコマンドをつくってみた。
みんなどうやってるんだろ

Progression Command用 MultiListenコマンド - wonderfl build flash online

MultiListen Command

PLAIN TEXT
Actionscript:
  1. import flash.events.Event;     
  2. import flash.events.IEventDispatcher;
  3. import jp.progression.commands.*;
  4.  
  5. /**
  6.  * Command Listen を複数のListenに対応したようなもの
  7.  * @author @quqjp
  8.  */
  9. class MultiListen extends Command {
  10.  
  11.     //dispatcherリスト
  12.     protected var dispatchers:Vector.<IEventDispatcher> = new Vector.<IEventDispatcher>();
  13.    
  14.     //イベントタイプリスト
  15.     protected var types:Vector.<String> = new Vector.<String>();
  16.        
  17.     //受信したイベントのDispatcher
  18.     protected var _dispatcher:IEventDispatcher;
  19.     public function get dispatcher():IEventDispatcher {
  20.         return _dispatcher;
  21.     }
  22.    
  23.     //受信したイベントのType
  24.     protected var _type:String;
  25.     public function get type():String {
  26.         return _type;
  27.     }
  28.        
  29.     //結果
  30.     protected var _success:Boolean = false;
  31.     public function get success():Boolean{
  32.         return _success;
  33.     }
  34.        
  35.     //完了時にCallするファンクション
  36.     public var commandComplete:Function;
  37.    
  38.     /**
  39.      * コンストラクタ
  40.      * @param   eventSetList    dispatcher:IEventDispatcher,eventType:Stringの順で配列を渡す e.g, d,e,d,e,d,e
  41.      * @param   initObject
  42.      */
  43.     public function MultiListen(eventSetList:Array,initObject:Object = null) { 
  44.         // 親クラスを初期化します。
  45.         super( _execute, _interrupt, initObject );
  46.            
  47.         if (eventSetList) {
  48.             var list:Array = eventSetList as Array;
  49.             if (list.length % 2 != 0) {
  50.                 throw new Error('引数が対になっていません。');
  51.             }
  52.             var l:uint = list.length;
  53.             var f:Boolean = true;
  54.             for (var i:uint = 0; i <l; i++) {
  55.                 if (f) {
  56.                     dispatchers.push(IEventDispatcher(list[i]));
  57.                 }else {
  58.                     types.push(String(list[i]));
  59.                 }
  60.                 f = !f;
  61.             }
  62.         }
  63.                
  64.     }
  65.    
  66.     /**
  67.      * 実行されるコマンドの実装です。
  68.      */
  69.     private function _execute():void {
  70.         var l:uint = dispatchers.length;
  71.         for (var i:uint = 0; i <l; i++) {
  72.             dispatchers[i].addEventListener(types[i],eventHandler);
  73.         }
  74.     }
  75.     //
  76.     private function eventHandler(e:Event):void {
  77.         var l:uint = dispatchers.length;
  78.         for (var i:uint = 0; i <l; i++) {
  79.             if (dispatchers[i] == e.target && types[i] == e.type) {
  80.                 this._dispatcher = dispatchers[i];
  81.                 this._type = types[i];
  82.                 this._success = true;
  83.             }
  84.         }
  85.         if (!this._success) {
  86.             throw new Error('対象のeventDispatcher、typeがみつかりません');
  87.         }
  88.         destroy();
  89.         if(Boolean(this.commandComplete)) this.commandComplete();
  90.         executeComplete();
  91.     }
  92.    
  93.     /**
  94.      * 中断されるコマンドの実装です。
  95.      */
  96.     private function _interrupt():void {
  97.         destroy();
  98.     }
  99.    
  100.     /**
  101.      * 破壊
  102.      */
  103.     protected function destroy():void{
  104.         if(dispatchers){
  105.             var l:uint = dispatchers.length;
  106.             for (var i:uint = 0; i <l; i++) {
  107.                 dispatchers[i].removeEventListener(types[i],eventHandler);
  108.             }
  109.         }
  110.     }      
  111. }